mIRC nickcomplete

이래저래 여태 쓰던 닉컴플리트 방식이 맘에 안들어 새로 만든것.

필요하신분은 가져가세염.

invalid-file

ON *:LOAD:{
  if (!%nc.tail) {
    set %nc.tail $input(닉컴플리트가 작동될때 필요한 말꼬리를 정해주세요 $+ $chr(13) $+ (기본값은 콜론(:)),eoq,NickComplete Prompt,:)
  }
}
#nickcomplete ON
ON *:INPUT:#:{
  if ($2 && !$inpaste) {
    if ($right($1,1) == %nc.tail) {
      var %nc = $left($1,$calc($len($1) - 1))
      msg # $nc.getnick(#,%nc) %nc.tail $2-
      halt
    }
  }
}
#nickcomplete END

alias nc.getnick {
  var %nc.chan = $1
  var %nc.nick = $2
  var %nc.nicklen = $len(%nc.nick)
  var %i = 1
  var %nc.loop = $nick(%nc.chan,0)
  while (%i <= %nc.loop) {
    if (%nc.nick == $left($nick(%nc.chan,%i),%nc.nicklen)) {
      return $nick(%nc.chan,%i)
      break
    }
    inc %i
  }
  if (%i >= %nc.loop) {
    var %j = 1
    var %nc.nickwm = * $+ %nc.nick $+ *
    while (%j <= %nc.loop) {
      if (%nc.nickwm iswm $nick(%nc.chan,%j)) {
        return $nick(%nc.chan,%j)
        break
      }
      inc %j
    }
    return %nc.nick
  }
}

alias nc.on {
  enable #nickcomplete
}

alias nc.off {
  disable #nickcomplete
}

alias nc {
  var %grp = #nickcomplete
  $iif($group(%grp).status,enable %grp,disable %grp)
}